dyn-gandi/flake.nix

{
  description = "A program to update an A record with the Gandi API v5.";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    poetry2nix = {
      url = "github:nix-community/poetry2nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    poetry2nix,
  } @ inputs: let
    supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
    forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
    pkgs = forAllSystems (system: nixpkgs.legacyPackages.${system});
    poetry = forAllSystems (system: poetry2nix.lib.mkPoetry2Nix {pkgs = pkgs.${system};});
  in {
    # `nix fmt`
    formatter = forAllSystems (system: nixpkgs.legacyPackages.${system}.alejandra);

    # `nix build`
    packages = forAllSystems (system: {
      default = poetry.${system}.mkPoetryApplication {
        projectDir = self;
      };
    });

    # `nix develop`
    devShells = forAllSystems (system: {
      default = pkgs.${system}.mkShellNoCC {
        packages = with pkgs.${system}; [
          (poetry.${system}.mkPoetryEnv {projectDir = self;})

          mypy
          python310Packages.types-requests
        ];
      };
    });

    # TODO Home Manager Module
    # homeManagerModules.default = import ./nix/hm-module.nix self;

    # NixOS Module
    nixosModules.default = import ./nix/module.nix inputs;
  };
}