dyn-gandi/flake.nix

{
  description = "A program to update an A record with the Gandi API v5.";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    poetry2nix-lib = {
      url = "github:nix-community/poetry2nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    poetry2nix-lib,
  } @ inputs: let
    supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
    forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
    pkgs = forAllSystems (system: nixpkgs.legacyPackages.${system});
    poetry2nix = forAllSystems (system: poetry2nix-lib.lib.mkPoetry2Nix {pkgs = pkgs.${system};});
  in {
    # `nix build`
    packages = forAllSystems (system: {
      default = poetry2nix.${system}.mkPoetryApplication {
        projectDir = self;
      };
    });

    # `nix fmt`
    formatter = forAllSystems (system: pkgs.${system}.alejandra);

    # `nix develop`
    devShells = forAllSystems (system: {
      default = let
        poetryEnv = poetry2nix.${system}.mkPoetryEnv {projectDir = self;};
      in
        pkgs.${system}.mkShellNoCC {
          packages = with pkgs.${system};
            [
              poetry
            ]
            ++ [poetryEnv];
        };
    });

    # TODO Home Manager Module
    # homeManagerModules.default = import ./nix/hm-module.nix self;

    # NixOS Module
    nixosModules.default = import ./nix/module.nix inputs;
  };
}